MaxDOS V6 系统备份查看器 批处理代码

@echo off
:_max
mode con: cols=62 lines=23
set bt=MaxDOS V6 系统备份查看器. 迈思工作室 Http://Pzz.Cn
color f0
title %bt%

:_m1
cls
echo.
echo MaxDOS V6 系统备份查看器
echo ═════════════════════════════
echo.
echo 1、打开存放备份镜像的目录
echo 2、删除已存在的镜像备份文件
echo 3、删除用于存放镜像的备份目录
echo 4、将用于存放镜像的目录设为可见
echo 5、将用于存放镜像的目录设为隐藏
echo 6、关闭备份文件夹(MaxBAK)的防删除保护
echo 7、打开备份文件夹(MaxBAK)的防删除保护
echo.
echo ═════════════════════════════
set pd=0
for %%m in (j i h g f e d) do if exist %%m:\maxbak set pd=%%m
set bf=MaxBAK\sysbak.max
set scd=0
for %%i in (j i h g f e d) do if exist %%i:\%bf% set scd=%%i
if %scd%==0 goto _ghoerr
echo 在 %scd%:\%bf% 发现使用MaxDOS一键备份生成的镜像.
goto _me
:_ghoerr
echo 对不起,未发现使用MaxDOS一键备份生成的镜像,请及时备份系统.
:_me
echo.
echo 为了避免GHOST备份的镜像被病毒删除故将MaxDOS一键备份生成的
echo 镜像保存为 sysbak.max 命名,存放于分区根目录的MaxBAK目录下.
echo.
set chi=
set /p chi= 请选择操作后回车:

if ''%chi%''=='''' goto _m1
if /i ''%chi%''==''1'' goto _op
if /i ''%chi%''==''2'' goto _dbakf
if /i ''%chi%''==''3'' goto _rdbak
if /i ''%chi%''==''4'' goto _atton
if /i ''%chi%''==''5'' goto _attof
if /i ''%chi%''==''6'' goto _cld
if /i ''%chi%''==''7'' goto _omd
goto _m1

:_cld
if %pd%==0 goto _er1
@rd /s /q %pd%:\MaxBAK\NODEL..\ >nul
@echo 已经关闭备份文件夹(MaxBAK)的防删除保护,按任意键返回!
pause >nul
goto _m1

:_omd
if %pd%==0 goto _er1
@md %pd%:\MaxBAK\NODEL..\ >nul
@echo 已经打开备份文件夹(MaxBAK)的防删除保护,按任意键返回!
pause >nul
goto _m1

:_op
if %pd%==0 goto _er1
start %pd%:\MaxBAK
goto _m1

:_dbakf
if %scd%==0 goto _er1
set /p yndel= 是否需要真的删除备份文件? [y=是 n=否]:
if ''%yndel%''=='''' goto _m1
if ''%yndel%''==''y'' del /f %scd%:\%bf%
if ''%yndel%''==''n'' goto _m1
echo 删除完成,按任意键返回.
pause >nul
goto _m1

:_atton
if %pd%==0 goto _er1
for %%k in (d: e: f: g:) do if exist %%k\MaxBAK\nul attrib -s -r -h %%k\MaxBAK
echo 已经将备份目录设为可见,按任意键返回.
pause >nul
goto _m1

:_attof
if %pd%==0 goto _er1
for %%j in (d: e: f: g:) do if exist %%j\MaxBAK\nul attrib +s +r +h %%j\MaxBAK
echo 已经将所有备份目录设为隐藏,按任意键返回.
pause >nul
goto _m1

:_rdbak
if %pd%==0 goto _er1
for %%l in (d: e: f: g:) do if exist %%l\MaxBAK\nul rd %%l\MaxBAK /s /q >nul
echo 删除完成,按任意键返回.
pause >nul
goto _m1

:_er1
echo 对不起未发现备份文件或备份文件夹,此功能失效,按任意键返回!
pause >nul
goto _m1

:exit